Justfile

# Foundry VTT data directory, git-ignored, created on first run
foundry_data := "foundry-data"

# List available recipes
default:
    @just --list

# Start the Foundry VTT server
up:
    mkdir -p {{foundry_data}}
    docker compose up

# Start the Foundry VTT server in the background
up-detached:
    mkdir -p {{foundry_data}}
    docker compose up -d

# Stop the Foundry VTT server
down:
    docker compose down

# Pull the newest image for the pinned Foundry VTT major version
pull:
    docker compose pull

# Build all modules (output goes to each module's dist/)
build:
    pnpm turbo build

# Watch a module and deploy on every rebuild to the Foundry data directory
# Usage: just dev sandbox
dev module:
    pnpm turbo build --filter=@rpg-made-simple/{{module}}^...
    FOUNDRY_DATA=`pwd`/{{foundry_data}} pnpm --filter @rpg-made-simple/{{module}} dev

# Build a single module and deploy it to the Foundry data directory
# Usage: just deploy sandbox
deploy module:
    pnpm turbo build --filter=@rpg-made-simple/{{module}}^...
    FOUNDRY_DATA=`pwd`/{{foundry_data}} pnpm --filter @rpg-made-simple/{{module}} build

# Start the documentation site in dev mode
docs:
    pnpm --filter @rpg-made-simple/docs docs:dev

# Release a module: validates the code, then pushes a version tag to trigger GitHub Actions.
# The version is read from the package's package.json (e.g. 0.1.0 -> tags-v0.1.0).
# Works for any workspace package that ships a Foundry manifest, under modules/ or bridges/.
# Usage: just release tags
release module:
    #!/usr/bin/env bash
    set -euo pipefail

    if [[ -n "$(git status --porcelain)" ]]; then
        echo "Error: working tree is not clean. Commit or stash changes before releasing."
        exit 1
    fi

    echo "Building dependencies for {{module}}..."
    pnpm turbo build --filter=@rpg-made-simple/{{module}}^...

    echo "Running typecheck for {{module}}..."
    pnpm turbo typecheck --filter=@rpg-made-simple/{{module}}

    echo "Building {{module}}..."
    pnpm turbo build --filter=@rpg-made-simple/{{module}}

    VERSION=$(pnpm --filter "@rpg-made-simple/{{module}}" list --depth -1 --json | node -e '
      const [pkg] = JSON.parse(require("node:fs").readFileSync(0, "utf-8"));
      if (pkg === undefined) { console.error("Unknown package: @rpg-made-simple/{{module}}"); process.exit(1); }
      console.log(pkg.version);
    ')
    TAG="{{module}}-v$VERSION"

    echo "Tagging: $TAG"
    git tag -a "$TAG" -m "Release $TAG"
    git push origin "$TAG"

    echo "Tag pushed. GitHub Actions will build and publish the release."