use ina219 with this library

[anomrak1989-netizen]

How to use ina219 with this library?
operating logic: determining the battery charge level based on the voltage level (example: 14V - 100%, 12V - 0%), determination of the discharge/charging/charged status by current: I<-0.1A - discharge, I>0.1A - charging, -0.1A<I<0.1A - fully charged.
The project is interesting, but my skills are not sufficient to implement such an idea.

[abratchik]

How to use ina219 with this library? operating logic: determining the battery charge level based on the voltage level (example: 14V - 100%, 12V - 0%), determination of the discharge/charging/charged status by current: I<-0.1A - discharge, I>0.1A - charging, -0.1A<I<0.1A - fully charged. The project is interesting, but my skills are not sufficient to implement such an idea.

sorry, what is inqa219?

[anomrak1989-netizen]

The INA219 is a current and voltage sensor with I2C interface.

[rgalverson]

I am using the Adafruit_INA219.h library with code based on this. You need a call to the ina219.begin() function in the setup(), and calls to getBusVoltage_V() and getCurrent_mA() in the loop().

[anomrak1989-netizen]

This is what happened in the end:

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Fonts/FreeMono12pt7b.h>  // Подключаем нужный шрифт
#include <GyverINA.h>              // Подключите библиотеку GyverINA
#include <HIDPowerDevice.h>
#include "HID.h"

// Размер дисплея
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

// Адрес дисплея по умолчанию (обычно 0x3C)
#define OLED_RESET -1  // не используем
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define MINUPDATEINTERVAL 10
INA219 ina(0.01f, 7.5f);  // Стандартный адрес, но другой шунт (0.01 Ом) и макс. ожидаемый ток (7.5 А)

// Параметры для уровня заряда по напряжению
const float voltageFullCharge = 17.4;     // при зарядке и заряжено + от сети
const float voltageFullDischarge = 16.3;  // при разрядке, для 5s LiFepo4 батареи
const float voltageEmpty = 15.3;          // 0% при 15.3 В

// Образец чтения данных - можно настроить
float voltage = 0;
char status;
int iIntTimer = 0;

// String constants
const char STRING_DEVICECHEMISTRY[] PROGMEM = "LiFePO4";
const char STRING_OEMVENDOR[] PROGMEM = "MyMiniUPS";
const char STRING_SERIAL[] PROGMEM = "UPS12";

const byte bDeviceChemistry = IDEVICECHEMISTRY;
const byte bOEMVendor = IOEMVENDOR;

PresentStatus iPresentStatus = {}, iPreviousStatus = {};

byte bRechargable = 1;
byte bCapacityMode = 2;  // units are in %%

// Physical parameters
const uint16_t iConfigVoltage = 1640;
uint16_t iVoltage = 1500, iPrevVoltage = 0;
uint16_t iRunTimeToEmpty = 0, iPrevRunTimeToEmpty = 0;
uint16_t iAvgTimeToFull = 7200;
uint16_t iAvgTimeToEmpty = 7200;
uint16_t iRemainTimeLimit = 600;
int16_t iDelayBe4Reboot = -1;
int16_t iDelayBe4ShutDown = -1;
uint16_t iManufacturerDate = 0;  // initialized in setup function
byte iAudibleAlarmCtrl = 2;      // 1 - Disabled, 2 - Enabled, 3 - Muted

// Parameters for ACPI compliancy
const byte iDesignCapacity = 100;
byte iWarnCapacityLimit = 10;  // warning at 10%
byte iRemnCapacityLimit = 5;   // low at 5%
const byte bCapacityGranularity1 = 1;
const byte bCapacityGranularity2 = 1;
byte iFullChargeCapacity = 100;

byte iRemaining = 0, iPrevRemaining = 0;

int iRes = 0;


void setup() {
  Serial.begin(57600);
  delay(2000);  // Ожидание инициализации

  // Инициализация дисплея
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    // Если инициализация не удалась — остановимся
    Serial.println(F("SSD1306 f"));
    for (;;)
      ;
  }
  display.clearDisplay();
  // Установка большого шрифта
  display.setFont(&FreeMono12pt7b);  // подключите свою шрифтовую библиотеку, если есть
  // Или используйте встроенные шрифты (проще):
  display.setTextColor(SSD1306_WHITE);
  display.setTextSize(1);  // размер текста
  display.setCursor(0, 0);
  display.display();

  // Инициализация INA219
  if (!ina.begin()) {
    Serial.println("INA219 f");
    while (1)
      ;
  }


  PowerDevice.begin();
  // Серийный номер задается особым образом, поскольку он формирует имя порта Arduino
  PowerDevice.setSerial(STRING_SERIAL);
  // Used for debugging purposes.
  PowerDevice.setOutput(Serial);


  PowerDevice.setFeature(HID_PD_PRESENTSTATUS, &iPresentStatus, sizeof(iPresentStatus));
  PowerDevice.setFeature(HID_PD_RUNTIMETOEMPTY, &iRunTimeToEmpty, sizeof(iRunTimeToEmpty));
  PowerDevice.setFeature(HID_PD_AVERAGETIME2FULL, &iAvgTimeToFull, sizeof(iAvgTimeToFull));
  PowerDevice.setFeature(HID_PD_AVERAGETIME2EMPTY, &iAvgTimeToEmpty, sizeof(iAvgTimeToEmpty));
  PowerDevice.setFeature(HID_PD_REMAINTIMELIMIT, &iRemainTimeLimit, sizeof(iRemainTimeLimit));
  PowerDevice.setFeature(HID_PD_DELAYBE4REBOOT, &iDelayBe4Reboot, sizeof(iDelayBe4Reboot));
  PowerDevice.setFeature(HID_PD_DELAYBE4SHUTDOWN, &iDelayBe4ShutDown, sizeof(iDelayBe4ShutDown));
  PowerDevice.setFeature(HID_PD_RECHARGEABLE, &bRechargable, sizeof(bRechargable));
  PowerDevice.setFeature(HID_PD_CAPACITYMODE, &bCapacityMode, sizeof(bCapacityMode));
  PowerDevice.setFeature(HID_PD_CONFIGVOLTAGE, &iConfigVoltage, sizeof(iConfigVoltage));
  PowerDevice.setFeature(HID_PD_VOLTAGE, &iVoltage, sizeof(iVoltage));
  PowerDevice.setStringFeature(HID_PD_IDEVICECHEMISTRY, &bDeviceChemistry, STRING_DEVICECHEMISTRY);
  PowerDevice.setStringFeature(HID_PD_IOEMINFORMATION, &bOEMVendor, STRING_OEMVENDOR);
  PowerDevice.setFeature(HID_PD_AUDIBLEALARMCTRL, &iAudibleAlarmCtrl, sizeof(iAudibleAlarmCtrl));
  PowerDevice.setFeature(HID_PD_DESIGNCAPACITY, &iDesignCapacity, sizeof(iDesignCapacity));
  PowerDevice.setFeature(HID_PD_FULLCHRGECAPACITY, &iFullChargeCapacity, sizeof(iFullChargeCapacity));
  PowerDevice.setFeature(HID_PD_REMAININGCAPACITY, &iRemaining, sizeof(iRemaining));
  PowerDevice.setFeature(HID_PD_WARNCAPACITYLIMIT, &iWarnCapacityLimit, sizeof(iWarnCapacityLimit));
  PowerDevice.setFeature(HID_PD_REMNCAPACITYLIMIT, &iRemnCapacityLimit, sizeof(iRemnCapacityLimit));
  PowerDevice.setFeature(HID_PD_CPCTYGRANULARITY1, &bCapacityGranularity1, sizeof(bCapacityGranularity1));
  PowerDevice.setFeature(HID_PD_CPCTYGRANULARITY2, &bCapacityGranularity2, sizeof(bCapacityGranularity2));

  uint16_t year = 2025, month = 12, day = 12;
  iManufacturerDate = (year - 1980) * 512 + month * 32 + day;  // from 4.2.6 Battery Settings in "Universal Serial Bus Usage Tables for HID Power Devices"
  PowerDevice.setFeature(HID_PD_MANUFACTUREDATE, &iManufacturerDate, sizeof(iManufacturerDate));
}


void loop() {
  float voltage = ina.getVoltage();  // Напряжение в Вольтах
  float current = ina.getCurrent();  // Ток в Амперах

  // Определение статуса
  char status;   //  0.1 - чтобы не прыгал статус при малейшем изменении тока в районе 0
  if (current > 0.1) {  
    status = 'C';  // Charging
  } else if (current < -0.1) {
    status = 'D';  // Discharging
  } else {
    status = 'O';  // FullyCharged + ACPresent
  }

  // Определение 'voltageFull' в зависимости от статуса
  float voltageFull;
  if (status == 'C' || status == 'O') {
    voltageFull = voltageFullCharge;  // 17.4В
  } else if (status == 'D') {
    voltageFull = voltageFullDischarge;  // 16.3В
  }

  // Определение заряда батареи по напряжению
  if (voltage >= voltageFull) {
    iRemaining = 100;
  } else if (voltage <= voltageEmpty) {
    iRemaining = 0;
  } else {
    iRemaining = (byte)(int)((voltage - voltageEmpty) / (voltageFull - voltageEmpty) * iFullChargeCapacity);
  }
  iRunTimeToEmpty = (uint16_t)round((float)iAvgTimeToEmpty * iRemaining / iFullChargeCapacity);

  // Характеристики состояния на основе статуса
  bool bCharging = (status == 'C');
  bool bDischarging = (status == 'D');
  bool bACPresent = (status == 'C' || status == 'O');
  bool FullyCharged = (status == 'O' && iRemaining == iFullChargeCapacity);


  // Зарядка
  iPresentStatus.Charging = bCharging;
  iPresentStatus.ACPresent = bACPresent;
  iPresentStatus.FullyCharged = (iRemaining == iFullChargeCapacity);

  // Разрядка
  if (bDischarging) {
    iPresentStatus.Discharging = 1;
    // if(iRemaining < iRemnCapacityLimit) iPresentStatus.BelowRemainingCapacityLimit = 1;

    iPresentStatus.RemainingTimeLimitExpired = (iRunTimeToEmpty < iRemainTimeLimit);

  } else {
    iPresentStatus.Discharging = 0;
    iPresentStatus.RemainingTimeLimitExpired = 0;
  }

  // Запрос на отключение
  if (iDelayBe4ShutDown > 0) {
    iPresentStatus.ShutdownRequested = 1;
    Serial.println("shutdown requested");
  } else
    iPresentStatus.ShutdownRequested = 0;

  // Неминуемо прекращение работы
  if ((iPresentStatus.ShutdownRequested) || (iPresentStatus.RemainingTimeLimitExpired)) {
    iPresentStatus.ShutdownImminent = 1;
    Serial.println("shutdown imminent");
  } else
    iPresentStatus.ShutdownImminent = 0;

  iPresentStatus.BatteryPresent = 1;

  //************ Delay ****************************************
  delay(1000);
  iIntTimer++;

  //************ Check if we are still online ******************

  if ((iPresentStatus != iPreviousStatus) || (iRemaining != iPrevRemaining) || (iRunTimeToEmpty != iPrevRunTimeToEmpty) || (iIntTimer > MINUPDATEINTERVAL)) {

    PowerDevice.sendReport(HID_PD_REMAININGCAPACITY, &iRemaining, sizeof(iRemaining));
    if (bDischarging) PowerDevice.sendReport(HID_PD_RUNTIMETOEMPTY, &iRunTimeToEmpty, sizeof(iRunTimeToEmpty));
    iRes = PowerDevice.sendReport(HID_PD_PRESENTSTATUS, &iPresentStatus, sizeof(iPresentStatus));

    iIntTimer = 0;
    iPreviousStatus = iPresentStatus;
    iPrevRemaining = iRemaining;
    iPrevRunTimeToEmpty = iRunTimeToEmpty;
  }

  Serial.println(iRemaining);
  Serial.println(iRunTimeToEmpty);
  Serial.println(iRes);

  // Очистка экрана для новых данных
  display.clearDisplay();


  // Вывод напряжения
  display.setCursor(6, 18);
  display.setTextSize(1);
  display.print("U " + String(voltage, 1));
  // Переносим курсор на 100 пикселей и выводим "V"
  display.setCursor(106, 18);
  display.print("V");

  // Вывод тока
  display.setCursor(6, 36);
  display.println("I " + String(current, 2));
  display.setCursor(106, 36);
  display.print("A");

  // Вывод процента заряда и статуса
  display.setCursor(6, 54);
  display.println("E " + String(iRemaining) + "% ");
  display.setCursor(106, 54);
  display.print(status);

  display.display();
  delay(1000);
}

Tested to work in Windows 10.